Electron Zeeman Interaction : Powder Lineshapes

Hamilton - Operator

The Hamilton operator (in energy units) in the principal axis system (PAS) of the g-matrix is :

H = β B.g.S;

β is the Bohr magneton, S the spin angular momentum operator, g is the g-matrix and B is the magnetic field vector.

In its PAS, the g-matrix is – of course – diagonal and has the diagonal elements (Subscript[g, XX]) (=gxx), (Subscript[g, YY]) = (gyy), and (Subscript[g, ZZ]) (=gzz):

g = (({{gxx, 0, 0}, {0, gyy, 0}, {0, 0, gzz}}));

S and B can be specified as:

S = {Sx, Sy, Sz};
B = {Bx, By, Bz};

For this general case, the Hamiltonian operator can be written as:

H

Sx, Sy and Sz ar the spin angular momentum operator components. Their effect on the spin functions (for S = 1/2) can be summarized as
(Subscript[S, z]) = (1/2)(({{1, 0}, {0, -1}})), (Subscript[S, x]) = (1/2)(({{0, 1}, {1, 0}})), and (Subscript[S, y]) = (i/2)(({{0, -1}, {1, 0}})).

Mathematica has different notations for multiplications of scalars and vectors/matrices. Therefore, we need to modify the expressions for H in order for Mathematica to recognize that Sx, Sy, and Sz are matrices instead of scalars.

H /. {a_ Sx -> a.Sx, a_ Sy -> a.Sy, a_ Sz -> a.Sz}

Now we can specify Sx, Sy and Sz

Sx = (1/2)(({{0, 1}, {1, 0}}));
Sy = (I/2)(({{0, -1}, {1, 0}}));
Sz = (1/2)(({{1, 0}, {0, -1}}));

... and the spin Hamiltonian becomes:

Simplify[H] // MatrixForm

We see that H is a hermitian matrix. Hermitian matrices have real eigenvalues, which Mathematica can easily determine...

evals = Simplify[Eigenvalues[H], β > 0]

The difference of the eigenvalues of the spin Hamiltonian corresponds to the spectral position of the EPR line:

ΔE = evals[[2]] - evals[[1]]

This equation shows that the spectral position of the EPR line depends on the orientation of the magnetic field with respect to the PAS of the g-matrix. In the simplest case, we assume that the g-matrix is isotropic, i.e., gxx = gyy = gzz = giso. It follows:

Simplify[ΔE /. {gxx -> giso, gyy -> giso, gzz -> giso}, giso > 0]

(Sqrt[(Bx^2)+(By^2)+(Bz^2)]) = |B0|, and it follows ΔE = giso β B0.

However, if the g-matrix is not isotropic, the direction of the magnetic field vector with respect to the principal axes of g becomes crucial for the determination of the EPR line position. We know that in the laboratory axis system (which in general does not coincide with the PAS of the g-matrix) the magnetic field vector points along the Z-direction, or, to be precise, we define the Z-direction of the laboratory axes coordinate system as the direction along which the magnetic field vector points to. With a suitable set of Euler angles, ϕ, θ and ψ, we can determine the components of the magnetic field vector along the PAS of the g-matrix.

R = (({{Cos[ϕ]Cos[θ] Cos[ψ]-Sin[ϕ] Sin[ψ], -Cos[ϕ] Cos[θ] Sin[ψ]-Sin[ϕ]Cos[ψ], Cos[ϕ]Sin[θ]}, {Sin[ϕ]Cos[θ] Cos[ψ]+Cos[ϕ] Sin[ψ], -Sin[ϕ] Cos[θ] Sin[ψ]+Cos[ϕ]Cos[ψ], Sin[ϕ]Sin[θ]}, {-Sin[θ]Cos[ψ], Sin[θ] Sin[ψ], Cos[θ]}}))

In any case, we need only two Euler angles, ϕ and θ, to unequivocally describe B in the PAS of g, thus we can set ψ to 0:

ψ = 0;

The transformation matrix R becomes:

R // MatrixForm

We use R to obtain the components Bx, By and Bz along the PAS of the g-matrix:

(({{Bx}, {By}, {Bz}})) = R.(({{0}, {0}, {B0}}))

... and the Hamiltonian operator becomes ...

H1 = Simplify[H] //MatrixForm

... and is now a function of the Euler angles θ and ϕ. The two eigenvalues of this hermitian matrix are again real:

evals = Simplify[Eigenvalues[H], {β > 0, B0 > 0}]

Again, the difference of the eigenvalues of the spin Hamiltonian corresponds to the spectral position of the EPR line:

ΔE = evals[[2]] - evals[[1]]

Simplify[% == B0 β (Sqrt[(gzz^2) ((Cos[θ])^2) + ((Sin[θ])^2)((gxx^2) ((Cos[ϕ])^2) + (gyy^2) ((Sin[ϕ])^2))])]

One can define an effective g-value (=geff) depending on the orientation of the magnetic field with respect to the g-matrix.

geff = ((ΔE)/(β B0))

We obtain the same result when we express the spin Hamiltonian in the laboratory coordinate system instead of the PAS of the g-matrix. In order to prove this, however, one should delete some values previously assigned to some variables.

Clear[H];
Clear[Sx];
Clear[Sy];
Clear[Sz];

In the laboratory frame, B = (0, 0, B0). For the g-matrix and the spin angular momentum operator S we can use the expressions above.

B = {0, 0, B0};

The Hamilton operator in the laboratory frame:

H = β B.Transpose[R].g.S;

H /. {a_ Sx -> a.Sx, a_ Sy -> a.Sy, a_ Sz -> a.Sz};

Since we have cleared the definitions of Sx, Sy and Sz, we have to redefine them now:

Sx = (1/2)(({{0, 1}, {1, 0}}));
Sy = (I/2)(({{0, -1}, {1, 0}}));
Sz = (1/2)(({{1, 0}, {0, -1}}));

... and the Hamilton operator becomes:

H2 = Simplify[H] // MatrixForm

This is exactly the same Hamiltonian that was obtained above (q.e.d.).

Simplify[H1 == H2]

Powder Lineshapes

In the previous section we have calculated the EPR line position of a sample with one single orientation of the magnetic field vector with respect to the g-matrix (single-crystal case). Very often, however, EPR experiments on solutions of radicals in the liquid or solid (e.g., frozen) state are to be carried out. In these cases, the individual radicals are randomly oriented with respect to each other and give rise to a so-called powder lineshape. In this chapter, we want to calculate such a powder lineshape originating from a non-symmetric g-matrix.

Clear[B];

Let us now define a function fgeff to calculate the effective g-value as a function of the orientation of the g-marix with respect to the magnetic field vector (as specified by the Euler angles θ and ϕ):

fgeff[gxx_, gyy_, gzz_, θ_, ϕ_] := (Sqrt[(gzz^2) ((Cos[θ])^2) + ((Sin[θ])^2)((gxx^2) ((Cos[ϕ])^2) + (gyy^2) ((Sin[ϕ])^2))])

We assume that the lineshape of each individual spin packet is purely Gaussian and that there is no orientation-dependent linewidth.

fgauss[B_, Bres_, ΔB_] := (Sqrt[((Log[2.0])/π)]) (2.0/(ΔB)) Exp[((-4.0 Log[2.0])/((ΔB)^2))(((B - Bres))^2)]

The function fderivgauss is used to calculate the first-derivative EPR spectra:

fderivgauss[B_, Bres_, ΔB_] := -(Sqrt[((Log[2.0])/π)]) ((16.0 Log[2.0](B - Bres))/((ΔB)^2)) Exp[((-4.0 Log[2.0])/((ΔB)^2))(((B - Bres))^2)]

Specification of parameters required for the calculation:

Bcf = 339.5 (10^(-3));
Bsw = 3.0 (10^(-3));
nBpts = 201;
υ = 9.5 (10^9);
gxx = 2.005;
gyy = 2.0025;
gzz = 1.997;
nθ = 121;
nϕ = 121;
ΔB = 0.1 (10^(-3));
β = 9.2740154 (10^(-24));
h = 6.6260755 (10^(-34));

Let us create a list of B-values at which we want to calculate the EPR signal intensity:

B = Table[Bcf - (Bsw/2.0) + (i - 1) (Bsw/(nBpts - 1)), {i, nBpts}];

Here comes a list of θ- and ϕ-values to be used to calculate the powder lineshape:

θ = Table[(i - 1) (π/(2.0 (nθ - 1))), {i, nθ}];
ϕ = Table[N[(i - 1) (π/((nϕ - 1)))], {i, nϕ}];

The signal intensities at the individual B-values are initially zero:

S = Table[0.0, {i, nBpts}];
Sderiv = Table[0.0, {i, nBpts}];

Now we start working, first for the EPR absorption signal ...

For[i=1, i ≤ nθ, i++, {
sinθ = Sin[θ[[i]]],
For[j=1, j ≤ nϕ, j++, {
Bres = ((h υ)/(fgeff[gxx, gyy, gzz, θ[[i]], ϕ[[j]]] β)),
For[k=1, k≤ nBpts, k++, 
If[Abs[B[[k]] - Bres] < ΔB,
S[[k]] += sinθ fgauss[B[[k]], Bres, ΔB]]]}]}]

... and now for the 1st-derivative lineshape...

For[i=1, i ≤ nθ, i++, {
sinθ = Sin[θ[[i]]],
For[j=1, j ≤ nϕ, j++, {
Bres = ((h υ)/(fgeff[gxx, gyy, gzz, θ[[i]], ϕ[[j]]] β)),
For[k=1, k≤ nBpts, k++, 
If[Abs[B[[k]] - Bres] < ΔB,
Sderiv[[k]] += sinθ fderivgauss[B[[k]], Bres, ΔB]]]}]}]

xy = Table[{B[[i]], S[[i]]}, {i, nBpts}];

xyderiv = Table[{B[[i]], Sderiv[[i]]}, {i, nBpts}];

Et voilà...

ListPlot[xy, PlotJoined -> True, PlotRange -> {{0.338, 0.341},{0, 1.5 (10^7)}}]

ListPlot[xyderiv, PlotJoined -> True, PlotRange -> {{0.338, 0.341},{-6.0 (10^6), 6.0 (10^6)}}]